CPVNAM=VDI;SPPNAM=Core
TALK=F;RUN( 1, 1)
TEXT(USP. pOTENTIAL FLOW
 
    GROUP 1. Run title and other preliminaries
TEXT(Flow Over Double-Wedge Airfoil. USP Test 13    
TITLE
  DISPLAY
     An inviscid fluid flows steadily past a double-wedge
  airfoil. The problem is solved in the same manner as in case
  115. The velocity components are computed by activation
  (through POTVEL) of a sequence in GREX3.
     The geometry of the problem is sketched below.
 
                       frictionless wall
     ____________________________________________________
 
                           ----------->
     ---->                                        ---->
 
                               _-_
     ---->                  __|***|__             ---->
   ^                     __|*********|__
  y|                  __|***************|__
   | ________________|*********************|______________
                       frictionless wall
                             z---->
  ENDDIS
 
    GROUP 4. Y-direction grid specification
GRDPWR(Y,80,1.0,1.0)
 
    GROUP 5. Z-direction grid specification
GRDPWR(Z,160,8.0,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(POT)
STORE(V1,W1,PRPS)
    GROUP 8.
INTEGER(LEVEL)
LEVEL = 2
mesg(Level of coarsening is :LEVEL:
mesg(Do you want to change it? (y/n)
readvdu(ans,char,n)
if(:ans:.eq.y)then
 mesg(Enter level of coarsening (0,1,2):
 readvdu(LEVEL,int,LEVEL)
 mesg(New level of coarsening is :LEVEL:
endif

USP    = T
UAUTO  = F
USPDBG = F
UTCPLT = T
USPVTK = T
USPIMB = F
MXLEV  = LEVEL 
MYLEV  = LEVEL
MZLEV  = LEVEL
DOMAT  = -1
MINPRP = -1
MAXPRP = 250
CELLST = 10
FACEST = 10

mesg(Do you want to view results in the centres of cells? (y/n)
readvdu(ans,char,n)
if(:ans:.eq.y)then
SPEDAT(SET,USPIO,VERTCENT,L,F)
endif




    GROUP 11. Initialization of variable or porosity fields
     The wedge is constructed porosities which are given the values 
     1.0 or 0.0 according to position. 
FIINIT(PRPS) = -1

DO II=1,40
+ PATCH(HPOR:II:,INIVAL,1,1,:II:,:II:,:40+II:,:120-II:,1,1)
+ INIT(HPOR:II:,PRPS,0.0,199)
ENDDO
 
    GROUP 13. Boundary conditions and special sources
   **Upstream boundary
PATCH(UPSTRM,LOW,1,1,1,NY,1,1,1,1)
COVAL(UPSTRM,POT,FIXVAL,4.0)
   **Downstream boundary
PATCH(DWNSTRM,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(DWNSTRM,POT,FIXVAL,-4.0)
 
    GROUP 15. Termination of sweeps
LSWEEP=200
 
    GROUP 16. Termination of iterations
    GROUP 19. Data communicated by satellite to GROUND
POTVEL=T
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
ECHO=T
SELREF = T; RESFAC =1.0E-12
TSTSWP=-1
NXPRIN= 1; NYPRIN=1
IYMON=NY/4+1;IZMON=NZ/2;IPLTF=2

> DOM,    SIZE,        1.000000E+00, 1.000000E+00, 8.000000E+00
> DOM,    MONIT,       5.000000E-01, 0.700000E+00, 4.000000E+00
> DOM,    SCALE,       1.000000E+00, 1.000000E+00, 1.000000E+00
> DOM,    SNAPSIZE,    1.000000E-02

if(LEVEL.gt.0)then
> OBJ,    NAME,        B1
> OBJ,    POSITION,    0.000000E+00, 0.000000E+00, 1.000000E+00
> OBJ,    SIZE,        1.000000E+00, 8.000000E-01, 6.000000E+00
> OBJ,    GEOMETRY,    fine
> OBJ,    ROTATION24,        1
> OBJ,    TYPE,        FINE_GRID_VOL
> OBJ,    LEVELS,       0.000000E+00, 0.000000E+00, 0.000000E+00
> OBJ,    AXES,        OYZ
endif

if(LEVEL.gt.1)then
> OBJ,    NAME,        B2
> OBJ,    POSITION,    0.000000E+00, 0.000000E+00, 1.500000E+00
> OBJ,    SIZE,        1.000000E+00, 7.000000E-01, 5.000000E+00
> OBJ,    GEOMETRY,    fine
> OBJ,    ROTATION24,        1
> OBJ,    TYPE,        FINE_GRID_VOL
> OBJ,    LEVELS,       1.000000E+00, 1.000000E+00, 1.000000E+00
> OBJ,    AXES,        OYZ
endif
STOP